REM Knowledge base for recommending a statistical technique for data analysis

PARAM [apptitle] = "Data analysis technique selector"
PARAM [titlecolor] = "#0000FF"

REM Rules to determine THE SUGGESTED TECHNIQUE CATEGORY

RULE [descriptive]
If [the analysis objective] = 'sample description'
Then [the suggested technique category] = 'descriptive statistics'

RULE [nonparametric 1]
If [the analysis objective] : 'hypothesis testing' 'estimating probability distribution parameters' and
[the measurement scale] : 'nominal' 'ordinal'
Then [the suggested technique category] = 'nonparametric statistics'

RULE [nonparametric 2]
If [the analysis objective] : 'hypothesis testing' 'estimating probability distribution parameters' and
[the measurement scale] : 'interval' 'ratio' 'ordinal but willing to treat as interval' and
[the number of data subsets] = 'one or two' and
[the variable to be analyzed] = 'not assumed to be normally distributed'
Then [the suggested technique category] = 'nonparametric statistics'

RULE [correlation/regression]
If [the analysis objective] = 'estimating model parameters'
Then [the suggested technique category] = 'correlation and regression analysis'

RULE [normal/unknown variance]
If [the analysis objective] : 'hypothesis testing' 'estimating probability distribution parameters' and
[the measurement scale] : 'interval' 'ratio' 'ordinal but willing to treat as interval' and
[the number of data subsets] = 'one or two' and
[the variable to be analyzed] = 'normally distributed with unknown variance'
Then [the suggested technique category] = 'hypothesis testing with unknown variance'

RULE [normal/known variance]
If [the analysis objective] : 'hypothesis testing' 'estimating probability distribution parameters' and
[the measurement scale] : 'interval' 'ratio' 'ordinal but willing to treat as interval' and
[the number of data subsets] = 'one or two' and
[the variable to be analyzed] = 'normally distributed with known variance'
Then [the suggested technique category] = 'hypothesis testing with known variance'

RULE [ANOVA]
If [the analysis objective] : 'hypothesis testing' 'estimating probability distribution parameters' and
[the measurement scale] : 'interval' 'ratio' 'ordinal but willing to treat as interval' and
[the number of data subsets] = 'two or more'
Then [the suggested technique category] = 'ANOVA'


REM Rules to determine THE SUGGESTED ANALYSIS APPROACH

REM Descriptive:
 
RULE [frequency tables]
If [the suggested technique category] = 'descriptive statistics' and
[the desired descriptive result] : 'a summary of response patterns'
Then [the suggested analysis approach] = 'to calculate frequency tables'

RULE [histograms]
If [the suggested technique category] = 'descriptive statistics' and
[the desired descriptive result] : 'a graphic summary of responses'
Then [the suggested analysis approach] = 'to draw histograms'

RULE [scatterplots]
If [the suggested technique category] = 'descriptive statistics' and
[the desired descriptive result] : 'a graphic presentation of variable relationships'
Then [the suggested analysis approach] = 'to draw scatterplots'

RULE [location]
If [the suggested technique category] = 'descriptive statistics' and
[the desired descriptive result] : 'a numerical measure of sample location'
Then [the suggested analysis approach] = 'to calculate the mean, median and mode'

RULE [spread]
If [the suggested technique category] = 'descriptive statistics' and
[the desired descriptive result] : 'a numerical measure of sample spread'
Then [the suggested analysis approach] = 'to calculate the range and sample variance'

REM Nonparametric statistics

RULE [rank correlation/contingency tables]
If [the suggested technique category] = 'nonparametric statistics' and
[the desired nonparametric result] : 'a measure of the degree to which 2 variables move together'
Then [the suggested analysis approach] = 'to calculate a rank correlation coefficient'

RULE [sign test]
If [the suggested technique category] = 'nonparametric statistics' and
[the desired nonparametric result] : 'a measure of the statistical significance of the value'
Then [the suggested analysis approach] = 'to perform a sign test'

RULE [Kruskall-Wallis]
If [the suggested technique category] = 'nonparametric statistics' and
[the desired nonparametric result] : 'a measure of the significance of 1 treatment on the variable'
Then [the suggested analysis approach] = 'to calculate the Kruskall-Wallis one-way ANOVA'

REM Correlation and regression analysis

RULE [correlation]
If [the suggested technique category] = 'correlation and regression analysis' and
[the desired correlation/regression result] : 'a measure of the degree to which 2 variables move together'
Then [the suggested analysis approach] = 'to calculate a sample correlation coefficient'

RULE [regression]
If [the suggested technique category] = 'correlation and regression analysis' and
[the desired correlation/regression result] : 'explanation or prediction with 1 independent variable'
Then [the suggested analysis approach] = 'to perform a simple regression analysis'

RULE [multiple regression]
If [the suggested technique category] = 'correlation and regression analysis' and
[the desired correlation/regression result] : 'explanation or prediction with 2 or more independent variables'
Then [the suggested analysis approach] = 'to perform a multiple regression analysis'

REM Hypothesis testing - normal/variance unknown

RULE [1 sample-t]
If [the suggested technique category] = 'hypothesis testing with unknown variance' and
[the desired variance unknown hypothesis testing result]: 'estimation or significance tests on one mean'
Then [the suggested analysis approach] = 'to perform a one sample t-test'

RULE [paired-t]
If [the suggested technique category] = 'hypothesis testing with unknown variance' and
[the desired variance unknown hypothesis testing result] : 'estimation or significance tests: before and after treatment mean difference'
Then [the suggested analysis approach] = 'to perform a paired sample t-test'

RULE [2 sample-t]
If [the suggested technique category] = 'hypothesis testing with unknown variance' and
[the desired variance unknown hypothesis testing result] : 'estimation or significance tests on two means'
Then [the suggested analysis approach] = 'to perform a two sample t-test'

REM Hypothesis testing - normal/variance known

RULE [1 sample-z]
If [the suggested technique category] = 'hypothesis testing with known variance' and
[the desired variance known hypothesis testing result] : 'estimation or significance tests on one mean'
Then [the suggested analysis approach] = 'to perform a one sample normal test'

RULE [paired-z]
If [the suggested technique category] = 'hypothesis testing with known variance' and
[the desired variance known hypothesis testing result] : 'estimation or significance tests: before and after treatment mean difference'
Then [the suggested analysis approach] = 'to perform a paired sample normal test'

RULE [2 sample-z]
If [the suggested technique category] = 'hypothesis testing with known variance' and
[the desired variance known hypothesis testing result] : 'estimation or significance tests on two means'
Then [the suggested analysis approach] = 'to perform a two sample normal test'

RULE [Chi-square]
If [the suggested technique category] = 'hypothesis testing with known variance' and
[the desired variance known hypothesis testing result] : 'estimation or significance of one variance'
Then [the suggested analysis approach] = 'to perform a Chi-square variance test'

RULE [F-ratio]
If [the suggested technique category] = 'hypothesis testing with known variance' and
[the desired variance known hypothesis testing result] : 'estimation or significance of equality of two variances'
Then [the suggested analysis approach] = 'to perform an F-test on the ratio of sample variances'

REM Hypothesis testing - ANOVA

RULE [1-way ANOVA]
If [the suggested technique category] = 'ANOVA' and
[the desired ANOVA testing result] = 'to determine the significance of one treatment on an interval scaled variable'
Then [the suggested analysis approach] = 'to perform a one-way ANOVA'

RULE [2-way ANOVA]
If [the suggested technique category] = 'ANOVA' and
[the desired ANOVA testing result] = 'to determine the significance of two treatments on an interval scaled variable'
Then [the suggested analysis approach] = 'to perform a two-way ANOVA'

REM Rules to determine THE MEASUREMENT SCALE

RULE [Nominal scale]
If [the analysis variable] = 'assigned unordered values'
Then [the measurement scale] = 'nominal'

RULE [Ordinal scale]
If [the analysis variable] = 'assigned values with inherent order'
Then [the measurement scale] = 'ordinal'

RULE [Ordinal-interval scale]
If [the analysis variable] = 'assigned values with inherent order that may be considered evenly spaced'
Then [the measurement scale] = 'interval'

RULE [Numeric]
If [the variable represents a continuous numeric value] = true
Then [the measurement scale] = 'interval'


REM final result HYPERLINKS

HYPERLINK [the suggested analysis approach] = "to perform a one-way ANOVA" "http://expertise2go.com/Android/StatRef.htm#AnalysisOfVariance"
HYPERLINK [the suggested analysis approach] = "to perform a two-way ANOVA" "http://expertise2go.com/Android/StatRef.htm#AnalysisOfVariance"
HYPERLINK [the suggested analysis approach] = "to calculate frequency tables" "http://expertise2go.com/Android/StatRef.htm#FrequencyTable"
HYPERLINK [the suggested analysis approach] = "to draw histograms" "http://expertise2go.com/Android/StatRef.htm#Histogram"
HYPERLINK [the suggested analysis approach] = "to draw scatterplots" "http://expertise2go.com/Android/StatRef.htm#Scatterplot"
HYPERLINK [the suggested analysis approach] = "to calculate the mean, median and mode" "http://expertise2go.com/Android/StatRef.htm#Descriptive"
HYPERLINK [the suggested analysis approach] = "to calculate the range and sample variance" "http://expertise2go.com/Android/StatRef.htm#Descriptive"
HYPERLINK [the suggested analysis approach] = "to prepare contingency tables" "http://expertise2go.com/Android/StatRef.htm#Contingency"
HYPERLINK [the suggested analysis approach] = "to perform a sign test" "http://expertise2go.com/Android/StatRef.htm#SignTest"
HYPERLINK [the suggested analysis approach] = "to calculate the Kruskall-Wallis one-way ANOVA" "http://expertise2go.com/Android/StatRef.htm#Kruskall"
HYPERLINK [the suggested analysis approach] = "to calculate a sample correlation coefficient" "http://expertise2go.com/Android/StatRef.htm#Correlation"
HYPERLINK [the suggested analysis approach] = "to perform a simple regression analysis" "http://expertise2go.com/Android/StatRef.htm#SimpleRegression"
HYPERLINK [the suggested analysis approach] = "to perform a multiple regression analysis" "http://expertise2go.com/Android/StatRef.htm#MultipleRegression"
HYPERLINK [the suggested analysis approach] = "to perform a one sample t-test" "http://expertise2go.com/Android/StatRef.htm#SingleT"
HYPERLINK [the suggested analysis approach] = "to perform a paired sample t-test" "http://expertise2go.com/Android/StatRef.htm#PairedT"
HYPERLINK [the suggested analysis approach] = "to perform a two sample t-test" "http://expertise2go.com/Android/StatRef.htm#TwoSampleT"
HYPERLINK [the suggested analysis approach] = "to perform a one sample normal test" "http://expertise2go.com/Android/StatRef.htm#SingleNormal"
HYPERLINK [the suggested analysis approach] = "to perform a paired sample normal test" "http://expertise2go.com/Android/StatRef.htm#PairedNormal"
HYPERLINK [the suggested analysis approach] = "to perform a two sample normal test" "http://expertise2go.com/Android/StatRef.htm#TwoSampleNormal"
HYPERLINK [the suggested analysis approach] = "to perform a Chi-square variance test" "http://expertise2go.com/Android/StatRef.htm#ChiSquare"
HYPERLINK [the suggested analysis approach] = "to perform an F-test on the ratio of sample variances" "http://expertise2go.com/Android/StatRef.htm#FTestVariance"


GOAL [the suggested analysis approach]
MAXVALS [the suggested analysis approach] 3
MAXVALS [the desired descriptive result] 4
MAXVALS [the desired nonparametric result] 2
MAXVALS [the desired correlation/regression result] 2
MAXVALS [the desired variance unknown hypothesis testing result] 2
MAXVALS [the desired variance known hypothesis testing result] 3

PROMPT [the analysis objective] MultChoice CF 
"What is your primary analysis objective?"
"sample description"
"hypothesis testing"
"estimating probability distribution parameters"
"estimating model parameters"

INFOLINK [the analysis objective]  "http://expertise2go.com/Android/Analysis.htm"

PROMPT [the desired descriptive result] AllChoice CF 
"Use of descriptive statistics is suggested. What type of result would you like to obtain? (check up to 4 that apply)
"a summary of response patterns"
"a graphic summary of responses"
"a graphic presentation of variable relationships"
"a numerical measure of sample location"
"a numerical measure of sample spread"

INFOLINK [the desired descriptive result]  "http://expertise2go.com/Android/StatRef.htm#Descriptive"

PROMPT [the desired nonparametric result] AllChoice CF  
"Use of nonparametric statistics is suggested. What type of result would you like to obtain? (check up to 2 that apply)"
"a measure of the degree to which 2 variables move together"
"a measure of the statistical significance of the value"
"a measure of the significance of 1 treatment on the variable"

INFOLINK [the desired nonparametric result]  "http://expertise2go.com/Android/StatRef.htm#Nonparametric"

PROMPT [the desired correlation/regression result] AllChoice CF 
"Use of correlation/regression analysis is suggested. What type of result would you like to obtain? (check up to 2 that apply)"
"a measure of the degree to which 2 variables move together"
"explanation or prediction with 1 independent variable"
"explanation or prediction with 2 or more independent variables"

INFOLINK [the desired correlation/regression result]  "http://expertise2go.com/Android/StatRef.htm#Correlation"

PROMPT [the desired variance unknown hypothesis testing result] AllChoice CF 
"Use of t statistics is suggested. What type of result would you like to obtain? (check up to 2 that apply)"
"estimation or significance tests on one mean"
"estimation or significance tests: before and after treatment mean difference"
"estimation or significance tests on two means"

INFOLINK [the desired variance unknown hypothesis testing result]  "http://expertise2go.com/Android/StatRef.htm#HypothesisTesting"

PROMPT [the desired variance known hypothesis testing result] AllChoice CF 
"Use of z (normal) statistics is suggested. What type of result would you like to obtain? (check up to 3 that apply)"
"estimation or significance tests on one mean"
"estimation or significance tests: before and after treatment mean difference"
"estimation or significance tests on two means"
"estimation or significance of one variance"
"estimation or significance of equality of two variances"

INFOLINK [the desired variance known hypothesis testing result]  "http://expertise2go.com/Android/StatRef.htm#HypothesisTesting"

PROMPT [the desired ANOVA testing result] MultChoice CF 
"Use of ANOVA is suggested. What type of result would you like to obtain?"
"to determine the significance of one treatment on an interval scaled variable"
"to determine the significance of two treatments on an interval scaled variable"

INFOLINK [the desired ANOVA testing result]  "http://expertise2go.com/Android/StatRef.htm#ANOVA"

PROMPT [the variable to be analyzed] MultChoice CF 
"The variable to be analyzed is:"
"normally distributed with known variance"
"normally distributed with unknown variance"
"not assumed to be normally distributed"

INFOLINK [the variable to be analyzed]  "http://expertise2go.com/Android/StatRef.htm#NormalDistribution"

PROMPT [the number of data subsets] MultChoice CF 
"The data to be analyzed is divided into how many subsets?"
"one or two"
"two or more"

PROMPT [the measurement scale] MultChoice CF
"The measurement scale for this item is:"
"nominal"
"ordinal
"ordinal but willing to treat as interval"
"interval"
"ratio"

INFOLINK [the measurement scale]  "http://expertise2go.com/Android/StatRef.htm#MeasurementScale"

PROMPT [the analysis variable] MultChoice CF
"The analysis variable is:"
'assigned unordered values'
'assigned values with inherent order'
'assigned values with inherent order that may be considered evenly spaced'

PROMPT [the variable represents a continuous numeric value] YesNo 
"Does this variable represent a continuous numeric value?"

REM Default values set when attribute has failed
DEFAULT [the measurement scale] = 'nominal' @ 80
DEFAULT [the variable to be analyzed] = 'not assumed to be normally distributed' @ 80